批處理如何備份文件夾和文件后發布文件夾至網站

小編給大家分享一下批處理如何備份文件夾和文件后發布文件夾至網站，希望大家閱讀完這篇文章之后都有所收獲，下面讓我們一起去探討吧！

先將"C:\網站"下對應"D:\工程1"下面的所有文件夾和文件備份到"D:\備份2012-9-1-52647"，然后再把"D:\工程1"發布到"C:\網站"。
用法：
backupAndPublish.bat "D:\工程1"

代碼如下:

@echo off
set SourceDir=%1
set now=%date:~0,4%-%date:~5,2%-%date:~8,2%-%time:~0,2%%time:~3,2%%time:~6,2%
::參數
set DestDir="C:\網站"
set BackDir="D:\備份%now%"
echo.
echo 正在備份
call:Backup %SourceDir% %DestDir% %BackDir%
echo.
echo 正在發布
call:Publish %SourceDir% %DestDir%
goto :eof
:: 主程序
:Backup
setlocal enabledelayedexpansion
set SourceDir=%~1
set DestDir=%~2
set BackDir=%~3
:: 計算源路徑長度
set SourceDirLen=0
set SourceDirStr=%SourceDir%
:next1
if not "%SourceDirStr%"=="" (
set /a SourceDirLen+=1
set "SourceDirStr=%SourceDirStr:~1%"
goto :next1
)
:: 備份
for /r "%SourceDir%" %%i in (*.*) do (
set BackPath=%%~dpi
set BackPath=%BackDir%!BackPath:~%SourceDirLen%!
set DestPath=%%i
set DestPath=%DestDir%!DestPath:~%SourceDirLen%!
set BackFilePath=%%i
set BackFilePath=%BackDir%!BackFilePath:~%SourceDirLen%!
echo !DestPath!
xcopy "!DestPath!" "!BackPath!" /r /y >nul 2>nul
if not exist "!BackFilePath!" (echo 備份復制失敗)
)
for /r "%SourceDir%" %%i in (\) do (
set SourcePath=%%i
set SourcePath=!SourcePath:~0,-1!
set BackPath=%BackDir%!SourcePath:~%SourceDirLen%!
md "!BackPath!" >nul 2>nul
)
setlocal disabledelayedexpansion
goto :eof
:: 發布
:Publish
set SourceDir=%1
set DestDir=%2
xcopy %SourceDir% %DestDir% /r /y /i /e
goto :eof

看完了這篇文章，相信你對“批處理如何備份文件夾和文件后發布文件夾至網站”有了一定的了解，如果想了解更多相關知識，歡迎關注億速云行業資訊頻道，感謝各位的閱讀！