ShaderLab學習小結（十一）貼圖模糊效果

建立cube，賦上貼圖，camera不動，旋轉cube，正面向著camera的貼圖清晰，或者說法線方向與camera的視方向平行的清晰，成90度的最為模糊，其它角度的在最清晰和最模糊之間
最清晰

此時其他幾個面最模糊

水平旋轉cube


可見隨著旋轉，原先的正面向右旋越來越模糊，而原先左側面越來越清晰。

shader代碼：

Shader "Custom/TestMoHu" {
    Properties {
        _MainTex ("Main Tex", 2D) = "white" {}
        _Scale("Scale", range(0,10)) = 10
    }
    SubShader {
        pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "unitycg.cginc"
            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _Scale;
            struct v2f {
                float4 pos : POSITION;
                float2 uv:TEXCOORD0;
                float z : TEXCOORD1;       //1.
            };
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.z = mul(unity_ObjectToWorld, v.vertex).z;                 //2.
                return o;
            }
            fixed4 frag(v2f IN):COLOR
            {
                float2 dsdx = ddx(IN.z)*_Scale;                       //3.
                float2 dsdy = ddy(IN.z)*_Scale;                       //4.
                fixed4 col = tex2D(_MainTex, IN.uv, dsdx, dsdy);     //5.
                return col;
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

Propeties里
_MainTex主紋理
_Scale 模糊強度系統，最小為0時無模糊效果，最大是10，模糊效果最大

1

float z : TEXCOORD1; //1.

結構體中定義這個z，用于存放物體世界坐標系下的z坐標

2

o.z = mul(unity_ObjectToWorld, v.vertex).z; //2.

轉換坐標至世界坐標系，取z值

3、4

float2 dsdx = ddx(IN.z)*_Scale;                       //3.
float2 dsdy = ddy(IN.z)*_Scale;                       //4.

以z值求x與y偏導數，再乘上系數_Scale，結果是二維向量

5

fixed4 col = tex2D(_MainTex, IN.uv, dsdx, dsdy); //5.

四個參數的tex2D函數進行紋理采樣，后兩個參數就是上面求得的兩個偏導數乘系數
最后返回這個顏色。