Solidit數組有什么用

這篇文章主要講解了“Solidit數組有什么用”，文中的講解內容簡單清晰，易于學習與理解，下面請大家跟著小編的思路慢慢深入，一起來研究和學習“Solidit數組有什么用”吧！

數組（Arrays）

數組可以聲明時指定長度，也可以是動態變長。對storage存儲的數組來說，元素類型可以是任意的，類型可以是數組，映射類型，結構體等。但對于memory的數組來說。如果作為public函數的參數，它不能是映射類型的數組，只能是支持ABI的類型。

一個元素類型為T，固定長度為k的數組，可以聲明為T[k]，而一個動態大小（變長）的數組則聲明為T[]。 還可以聲明一個多維數組，如聲明一個類型為uint的數組長度為5的變長數組（5個元素都是變長數組），可以聲明為uint[][5]。（注意，相比非區塊鏈語言，多維數組的長度聲明是反的。）

要訪問第三個動態數組的第二個元素，使用x[2][1]。數組的序號是從0開始的，序號順序與定義相反。

bytes和string是一種特殊的數組。bytes類似byte[]，但在外部函數作為參數調用中，bytes會進行壓縮打包。string類似bytes，但不提供長度和按序號的訪問方式（目前）。 所以應該盡量使用bytes而不是byte[]。

可以將字符串s通過bytes(s)轉為一個bytes，可以通過bytes(s).length獲取長度，bytes(s)[n]獲取對應的UTF-8編碼。通過下標訪問獲取到的不是對應字符，而是UTF-8編碼，比如中文編碼是多字節，變長的，所以下標訪問到的只是其中的一個編碼。 類型為數組的狀態變量，可以標記為public，從而讓Solidity創建一個訪問器，如果要訪問數組的某個元素，指定數字下標就好了。（稍后代碼事例）

創建內存數組

可使用new關鍵字創建一個memory的數組。與stroage數組不同的是，你不能通過.length的長度來修改數組大小屬性。我們來看看下面的例子：

pragma solidity ^0.4.16;

contract C {
    function f(uint len) public pure {
        uint[] memory a = new uint[](7);
                
        //a.length = 100;  // 錯誤
        bytes memory b = new bytes(len);
        // Here we have a.length == 7 and b.length == len
        a[6] = 8;
    }
}

數組常量及內聯數組

數組常量，是一個數組表達式（還沒有賦值到變量）。下面是一個簡單的例子：

pragma solidity ^0.4.16;

contract C {
    function f() public pure {
        g([uint(1), 2, 3]);
    }
    function g(uint[3] _data) public pure {
        // ...
    }
}

通過數組常量，創建的數組是memory的，同時還是定長的。元素類型則是使用剛好能存儲的元素的能用類型，比如[1, 2, 3]，只需要uint8即可存儲，它的類型是uint8[3] memory。

由于g()方法的參數需要的是uint（默認的uint表示的其實是uint256），所以需要對第一個元素進行類型轉換，使用uint(1)來進行這個轉換。

還需注意的一點是，定長數組，不能與變長數組相互賦值，我們來看下面的代碼：

//  無法編譯
pragma solidity ^0.4.0;

contract C {
    function f() public {
        // The next line creates a type error because uint[3] memory
        // cannot be converted to uint[] memory.
        uint[] x = [uint(1), 3, 4];
    }
}

已經計劃在未來移除這樣的限制。當前因為ABI傳遞數組還有些問題。

成員

length屬性

數組有一個.length屬性，表示當前的數組長度。storage的變長數組，可以通過給.length賦值調整數組長度。memory的變長數組不支持。 不能通過訪問超出當前數組的長度的方式，來自動實現改變數組長度。memory數組雖然可以通過參數，靈活指定大小，但一旦創建，大小不可調整。

push方法

storage的變長數組和bytes都有一個push方法（string沒有），用于附加新元素到數據末端，返回值為新的長度。

限制情況

當前在external函數中，不能使用多維數組。

另外，基于EVM的限制，不能通過外部函數返回動態的內容。

contract C {
     function f() returns (uint[]) { ... }
      }

在這個的例子中，如果通過web.js調用能返回數據，但從Solidity中調用不能返回數據。一種繞過這個問題的辦法是使用一個非常大的靜態數組。

pragma solidity ^0.4.16;

contract ArrayContract {
    uint[2**20] m_aLotOfIntegers;
    // 這里不是兩個動態數組的數組，而是一個動態數組里，每個元素是長度為二的數組。
    bool[2][] m_pairsOfFlags;
    // newPairs 存在 memory里，因為是函數參數
    function setAllFlagPairs(bool[2][] newPairs) public {
        m_pairsOfFlags = newPairs;
    }

    function setFlagPair(uint index, bool flagA, bool flagB) public {
        // 訪問不存在的index會拋出異常
        m_pairsOfFlags[index][0] = flagA;
        m_pairsOfFlags[index][1] = flagB;
    }

    function changeFlagArraySize(uint newSize) public {
        // 如果新size更小, 移除的元素會被銷毀
        m_pairsOfFlags.length = newSize;
    }

    function clear() public {
        // 銷毀
        delete m_pairsOfFlags;
        delete m_aLotOfIntegers;
        // 同銷毀一樣的效果
        m_pairsOfFlags.length = 0;
    }

    bytes m_byteData;

    function byteArrays(bytes data) public {
        // byte arrays ("bytes") are different as they are stored without padding,
        // but can be treated identical to "uint8[]"
        m_byteData = data;
        m_byteData.length += 7;
        m_byteData[3] = byte(8);
        delete m_byteData[2];
    }

    function addFlag(bool[2] flag) public returns (uint) {
        return m_pairsOfFlags.push(flag);
    }

    function createMemoryArray(uint size) public pure returns (bytes) {
        // Dynamic memory arrays are created using `new`:
        uint[2][] memory arrayOfPairs = new uint[2][](size);
        // Create a dynamic byte array:
        bytes memory b = new bytes(200);
        for (uint i = 0; i < b.length; i++)
            b[i] = byte(i);
        return b;
    }
}

感謝各位的閱讀，以上就是“Solidit數組有什么用”的內容了，經過本文的學習后，相信大家對Solidit數組有什么用這一問題有了更深刻的體會，具體使用情況還需要大家實踐驗證。這里是億速云，小編將為大家推送更多相關知識點的文章，歡迎關注！