DOS批處理中set命令怎么用

這篇文章將為大家詳細講解有關DOS批處理中set命令怎么用，小編覺得挺實用的，因此分享給大家做個參考，希望大家閱讀完這篇文章后可以有所收獲。

一、用set命令設置自定義變量

顯示、設置或刪除 cmd.exe 環境變量。

SET [variable=[string]]
variable 指定環境變量名。
string 指定要指派給變量的一系列字符串。

要顯示當前環境變量，鍵入不帶參數的 SET。

SET 命令不允許變量名含有等號。

注意：以下用法將清除變量variable的值，使其變成未定義狀態。

SET variable=

上面等號后面無任何符號，如果寫成SET variable=""，此時變量值并不為空，而是等于兩個引號，即""

例子:

@echo off
 set var=我是值
 echo %var%
 pause

看 set var=我是值 ,這就是BAT直接在批處理中設置變量的方法!

set 是命令 var是變量名 =號右邊的"我是值"是變量的值

在批處理中我們要引用這個變就把var變量名用兩個%(百分號)擴起來,如%var%

SET還可以提供一個交互界面,讓用戶自己輸入變量的值,然后我們在來根據這個值來做相應操作,現在我就來說說SET的這種語法,只需要加一個"/P"參數就可以了!

SET /P variable=[promptString]

例子:

@echo off
set /p var=請輸入變量的值:
echo 您輸入了 %var% ~_~
pause

set /p 是命令語法  var是變量名    =號右邊的"請輸入變量的值: ",這個是提示語,不是變量的值了!
運行后,我們在提示語后面直接輸入1,就會顯示一行您輸入了 1 ~_~

好了,先回顧到這,現在講SET其他功能

使用set /?查看SET的幫助我們發現SET除了我上面講的
SET [variable=[string]]
SET /P variable=[promptString]

這兩種語法外,還有如下幾種語法:
SET /A expression

環境變量替換已如下增強:
%PATH:str1=str2%
%PATH:~10,5%
%PATH:~-10%
%PATH:~0,-2%

這機種語法有什么用處呢?下面我們來一個個講解他們!

二、用set命令進行簡單計算

語法：SET /A expression

/A 命令行開關指定等號右邊的字符串為被評估的數字表達式。該表達式評估器很簡單并以遞減的優先權順序支持下列操作:
    ()                  -分組
    ! ~ -               -一元運算符
    * / %               -算數運算符
    + -                 -算數運算符
    << >>               -二進制邏輯移位
    &                   -二進制按位“與”
    ^                   -二進制按位“異”
    |                   -二進制按位“或”
    = *= /= %= += -=    -算數賦值
    &= ^= |= <<= >>=    -二進制運算賦值
    ,                   -表達式分隔符

如果 SET /A 在命令腳本外的命令行執行的，那么它顯示該表達式的最后值。除十六進制有 0x 前綴， 八進制有 0 前綴的，數字值為十進位數字。因此， 0x12 與 18 和 022相同。請注意八進制公式可能很容易搞混: 08 和 09 是無效的數字，因為 8 和 9 不是有效的八進制位數。

上面這些是系統幫助里的內容,看著是不是有點暈，沒關系我來簡單解釋一下:set的/A參數就是讓SET可以支持數學符號進行加減等一些數學運算!

注意：一般的運算常為十進制運算，如果數字字符串最左邊為0，將被認為是八進制，從而出錯。比如，0812之類的數字不能參與十進制運算，轉換方法為：10812-10000

例：

set aa=0812
set /a aa=1%aa%-10000
echo %aa%

結果為：812

例：

@echo off
set /p input=請輸入計算表達式：
set /a var=%input%
echo 計算結果：%input%=%var%
pause

上面的例子是龍卷風設計的，很好用喲，請看下面幾個運算過程：

注意：DOS計算只能進行整數運算，精確到整數

請輸入計算表達式：1+9+20+30-10
計算結果：1+9+20+30-10=50
請按任意鍵繼續. . .

請輸入計算表達式：10/3    #除法只能精確到整數
計算結果：10/3=3
請按任意鍵繼續. . .

請輸入計算表達式：-100+62  #負數
計算結果：-100+62=-38
請按任意鍵繼續. . .

請輸入計算表達式：100%3    ＃求余數
計算結果：100%3=1
請按任意鍵繼續. . .
注意：以上的求余數運算符%在批處理程序中必須寫成%%

請輸入計算表達式：(25+75)*2/(15+5)   #括號
計算結果：(25+75)*2/(15+5)=10
請按任意鍵繼續. . .

請輸入計算表達式：1234567890*9876543210   #范圍
無效數字。數字精確度限為 32 位。
計算結果：1234567890*9876543210=
請按任意鍵繼續. . .

注意：上面的計算過程顯示，DOS計算只能精確到32位，這個32位是指二進制32位，其中最高位為符號位（0為正，1為負），低位31位為數值。31個 1換成十進制為2147483647，所以DOS計算的有效值范圍是-2147483648至2147483647，超出該數值范圍時計算出錯，請看下面 的計算過程：

請輸入計算表達式：2147483647-1    #最大值減1，值有效
計算結果：2147483647-1=2147483646
請按任意鍵繼續. . .

請輸入計算表達式：2147483647+1    #最大值加1，出錯，結果為最小值
計算結果：2147483647+1=-2147483648
請按任意鍵繼續. . .

請輸入計算表達式：-2147483648-1   #最小值減1，出錯，結果為最大值
計算結果：-2147483648-1=2147483647
請按任意鍵繼續. . .

運行set /a a=1+1,b=2+1,c=3+1后會顯示一個4,但我們用echo %a% %b% %c%后看結果,會發現其他數學運算也有效果!,這就是表達式分隔符"逗"號的作用!

有時候我們需要直接在原變量進行加減操作就可以用這種語法set /a var+=1  這樣的語法對應原始語法就是set /a var = %var% + 1
都是一樣的結果,在原變量的值上在進行數學運算,不過這樣寫簡單一點再來一個:
set /a var*=2
其他都這么用,只要幫助里有這個語法!

另外還有一些用邏輯或取余操作符,這些符號,按照上面的使用方法會報錯的

比如我們在CMD里輸入set /a var=1 & 1 "與運算",他并不會顯示為1,而是報錯,為什么?對于這樣的"邏輯或取余操作符",我們需要把他們用雙引號引起來,也可以用轉義字符^，看例子

set /a var= 1 "&" 1 這樣結果就顯示出來了,其他邏輯或取余操作符用法
set /a var= 1 "+" 1 異運算
set /a var= 1 "%" 1  取模運算
set /a var= 3 "<<" 2 左移位運算， 3的二進制為11，左移2位為1100，換成十進制就是12，自行驗證
set /a var= 4 ">>" 2右移位運算，4的二進制為100，右移動2位為1，結果為1

龍卷風補充：凡是按位計算均需換算成二進制。

思考題：求2的n次方
參考答案：

@echo off
set /p n=請輸入2的幾次方: 
set /a num=1^<^<n
echo %num%
pause

運行結果：
請輸入2的幾次方: 3
8
請按任意鍵繼續. . .

請輸入2的幾次方: 10
1024
請按任意鍵繼續. . .

請輸入2的幾次方: 15
32768
請按任意鍵繼續. . .

三、用set命令進行字符串處理

1、字符串替換

好了，符號說到這，現在說%PATH:str1=str2%
上面語法的意思就是：將字符串變量%PATH%中的str1替換為str2
這個是替換變量值的內容,看例子

@echo off
set a= bbs. verybat. cn
echo 替換前的值: "%a%"
set var=%a: =%
echo 替換后的值: "%var%"
pause

運行顯示：（龍卷風添加）
替換前的值: " bbs. verybat. cn"
替換后的值: "bbs.verybat.cn"

對比一下,我們發現他把變量%a%的空格給替換掉了,從這個例子,我們就可以發現
%PATH:str1=str2%這個操作就是把變量%PATH%的里的str1全部用str2替換

比如我們把上面的例子改成這樣

@echo off
set a=bbs.verybat.cn
echo 替換前的值: "%a%"
set var=%a:.=傷腦筋%
echo 替換后的值: "%var%"
pause

運行顯示：
替換前的值: "bbs.verybat.cn"
替換后的值: "bbs傷腦筋verybat傷腦筋cn"

解釋set var=%a:.=傷腦筋%
set是命令 var是變量名 字a是要進行字符替換的變量的值,"."為要替換的值,
"傷腦筋"為替換后的值!
執行后就會把變量%a%里面的"."全部替換為"傷腦筋"
這就是set的替換字符的很好的功能! 替換功能先講到這，下面將字符串截取功能

請注意：字符串的替換和截取功能在引用變量的地方均可以，并不一定必須要有set命令
例：

@echo off
set a=bbs.verybat.cn
echo 替換前的值: "%a%"
echo 替換后的值: "%a:.=傷腦筋%"
pause

此例在echo語句中就替換了字符串，效果一樣。

2、字符串截取

**********************************************
截取功能統一語法格式為：%a:~[m[,n]]%
**********************************************
方括號表示可選，%為變量標識符，a為變量名，不可少，冒號用于分隔變量名和說明部分，符號～可以簡單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長度（缺省為全部）

%PATH:~10,5% 這個什么意思,看例子:

截取功能例子1：

@echo off
set a=bbs.verybat.cn
set var=%a:~1,2%
echo %var%
pause

執行后,我們會發現只顯示了"bs"兩個字母,我們的變量%a%的值不是為bbs.verybat.cn嗎？
怎么只顯示了第2個字母和第3個字母"bs",分析一結果我們就可以很容易看出%PATH:~10,5%就是顯示變量PATH里從11位（偏移量10）開始的5個字符!
分析set var=%a:~1,2%
set是命令，var是變量值，a要進行字符操作的變量，"1"從變量"a"第幾位開始顯示，"2"表示顯示幾位。
合起來就是把變量a的值從第2位（偏移量1）開始,把2個字符賦予給變量var
這樣應該明白了吧~

其他兩種語法
%PATH:~-10%
%PATH:~0,-2%
他們也是顯示指定變量指定幾位的值的意思

%PATH:~-10% 看例子

截取功能例子2：

@echo off
set a=bbs.verybat.cn
set var=%a:~-3%
echo %var%
pause

運行結果：.cn
這個就是把變量a倒數3位的值給變量VAR

當然我們也可以改成這樣
截取功能例子3：

@echo off
set a=bbs.verybat.cn
set var=%a:~3%
echo %var%
pause

運行顯示：.verybat.cn
這個就是把變量a的從第3位開始后面全部的值給變量VAR

%PATH:~0,-2% 例子

截取功能例子4：

@echo off
set a=bbs.verybat.cn
set var=%a:~0,-3%
echo %var%
pause

執行后,我們發現顯示的是"bbs.verybat",少了".cn"
從結果分析,很容易分析出,這是把變量a的值從0位開始,
到倒數第三位之間的值全部賦予給var

如果改成這樣

截取功能例子5：

@echo off
set a=bbs.verybat.cn
set var=%a:~2,-3%
echo %var%
pause

運行顯示：s.verybat
那么他就是顯示從第3位（偏移量2）開始減去倒數三位字符的值,并賦予給變量var

講得好，例子就是說明問題，為便于記憶，龍卷風小節如下：

a=bbs.verybat.cn
%a:~1,2% ＝“bs” 偏移量1，從第二位開始向右取2位
%a:~-3% ＝“.cn” 偏移量負3，即倒數3位（也可理解為留下右邊3位），右取全部
%a:~3% ＝“.verybat.cn” 偏移量3（也可理解為去掉左邊3位），右取全部
%a:~0,-3% ＝“bbs.verybat” 偏移量0，右取長度至負3，即倒數3位
%a:~2,-3% ＝“s.verybat” 偏移量2，右取長度至負3，即倒數3位

**********************************************
所以，截取功能統一語法格式為：%a:~[m[,n]]%
**********************************************
方括號表示可選，%a%為變量名，不可少，冒號用于分隔變量名和說明部分，符號～可以簡單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長度（缺省為全部）
上面所述用法其實相當于vbs函數mid、left、right
%a:~0,n% 相當于函數left(a,n) 取左邊n位
%a:~-m% 相當于函數right（a,m） 取右邊m位
%a:~m,n% 相當于函數mid(a,m+1,n) 從m+1位開始取n位
%a:~m,-n% 相當于函數mid(a,m+1,len(a)-m-n),從m+1位開始，至倒數n+1位
%a:~m % 相當于函數mid(a,m+1,len(a)-m) 或者right(a,len(a)-m)，從m+1位開始取右邊全部。

思考題目：輸入任意字符串，求字符串的長度
參考答案：

@echo off
set /p str=請輸入任意長度的字符串:
echo 你輸入了字符串:"%str%"
call :stringlenth "%str%" num
echo 字符串長度為：%num%
pause
exit

:StringLenth
::---------字符串長度計算子程序
::---------參數%1為字符串(如有空格，請用引號括起來)
::---------參數%2為返回變量名稱，不能含空格或特殊字符
::@echo off
set theString=%~1
if not defined theString goto :eof
set Return=0
:StringLenth_continue
set /a Return+=1
set thestring=%thestring:~0,-1%
if defined thestring goto StringLenth_continue
if not "%2"=="" set %2=%Return%
goto :eof

關于“DOS批處理中set命令怎么用”這篇文章就分享到這里了，希望以上內容可以對大家有一定的幫助，使各位可以學到更多知識，如果覺得文章不錯，請把它分享出去讓更多的人看到。