易語言怎么實現編輯框加背景圖片

小編給大家分享一下易語言怎么實現編輯框加背景圖片，希望大家閱讀完這篇文章之后都有所收獲，下面讓我們一起去探討吧！

DLL代碼

.版本 2
.DLL命令 CreatePatternBrush, 整數型, "gdi32", "CreatePatternBrush"
  .參數 hBitmap, 整數型
.DLL命令 GetWindowLong, 整數型, "user32", "GetWindowLongA"
  .參數 hwnd, 整數型
  .參數 nIndex, 整數型
.DLL命令 SetWindowLong, 整數型, "user32", "SetWindowLongA"
  .參數 hwnd, 整數型
  .參數 nIndex, 整數型
  .參數 dwNewLong, 整數型
.DLL命令 CallWindowProcA, 整數型, , "CallWindowProcA"
  .參數 lproc, 整數型
  .參數 hwnd, 整數型
  .參數 umsg, 整數型
  .參數 wparam, 整數型
  .參數 lparam, 整數型
.DLL命令 DeleteObject, 整數型, "gdi32", "DeleteObject"
  .參數 hObject, 整數型
.DLL命令 SetBkMode, 整數型, "gdi32", "SetBkMode"
  .參數 hdc, 整數型
  .參數 nBkMode, 整數型

常量表

.版本 2
.常量 GWL_WNDPROC, "-4"
.常量 WM_CTLCOLOREDIT, "307"
.常量 TRANSPARENT, "1"

編輯框加背景代碼

.版本 2
.程序集 窗口程序集1
.程序集變量 lpOldProc, 整數型
.程序集變量 hBlackBrush, 整數型
.子程序 __啟動窗口_創建完畢
.局部變量 圖片, 對象
圖片框1.可視 ＝ 假
圖片.創建圖片對象 (圖片框1.圖片)
hBlackBrush ＝ CreatePatternBrush (圖片.讀數值屬性 (“handle”, ))
lpOldProc ＝ GetWindowLong (取窗口句柄 (), #GWL_WNDPROC)
SetWindowLong (取窗口句柄 (), #GWL_WNDPROC, 到數值 (&WndProc))
.子程序 WndProc, 整數型
.參數 hwnd, 整數型
.參數 umsg, 整數型
.參數 wparam, 整數型
.參數 lparam, 整數型
.如果真 (umsg ＝ #WM_CTLCOLOREDIT)
  SetBkMode (wparam, #TRANSPARENT)
  返回 (hBlackBrush)
.如果真結束
返回 (CallWindowProcA (lpOldProc, hwnd, umsg, wparam, lparam))
.子程序 __啟動窗口_可否被關閉, 邏輯型
.如果真 (hBlackBrush ＞ 0)
  DeleteObject (hBlackBrush)
.如果真結束
.子程序 _編輯框1_內容被改變
編輯框1.重畫 ()
.子程序 _編輯框1_滾輪被滾動, 邏輯型
.參數 滾動距離, 整數型
.參數 功能鍵狀態, 整數型
編輯框1.重畫 ()

運行結果：

看完了這篇文章，相信你對“易語言怎么實現編輯框加背景圖片”有了一定的了解，如果想了解更多相關知識，歡迎關注億速云行業資訊頻道，感謝各位的閱讀！