.版本 2
.支持庫 iext
.支持庫 shell
.支持庫 xplib
.程序集 窗口程序集1
.程序集變量 搜尋位置, 整數型
.程序集變量 當前被搜尋文本, 文本型
.程序集變量 起始
.程序集變量 sj1
.程序集變量 sj2
.子程序 _驅動器框_驅動器被改變
連續賦值 (驅動器框.驅動器 ＋ “:\”, 目錄框1.目錄, 文件框1.目錄)
.子程序 _目錄框1_目錄被改變
文件框1.目錄 ＝ 目錄框1.目錄
.子程序 _文件框1_雙擊選擇
待替換文件列表框.插入表項 (, 目錄框1.目錄 ＋ “\” ＋ 文件框1.被選擇文件, , , , )
.子程序 _類型組合框_列表項被選擇
文件框1.通配符 ＝ 類型組合框.取項目文本 (類型組合框.現行選中項)
.子程序 _系統文件選擇框_被單擊
.如果 (系統文件選擇框.選中 ＝ 真)
  文件框1.系統 ＝ 真
.否則
  文件框1.系統 ＝ 假
.如果結束
.子程序 _隱藏文件選擇框_被單擊
.如果 (隱藏文件選擇框.選中 ＝ 真)
  文件框1.隱藏 ＝ 真
.否則
  文件框1.隱藏 ＝ 假
.如果結束
.子程序 _加入_被選擇
.局部變量 text, 文本型, , "0"
.局部變量 cs
.如果真 (文件框1.被選擇文件 ＝ “”)
  返回 ()
.如果真結束
text ＝ 分割文本 (文件框1.被選擇文件, “;”, )
.計次循環首 (取數組成員數 (text), cs)
  .如果 (取文本右邊 (目錄框1.目錄, 1) ＝ “\”)
    待替換文件列表框.插入表項 (, 目錄框1.目錄 ＋ text [cs], , , , )
  .否則
    待替換文件列表框.插入表項 (, 目錄框1.目錄 ＋ “\” ＋ text [cs], , , , )
  .如果結束
.計次循環尾 ()
.子程序 _刪除_被選擇
.如果真 (待替換文件列表框.現行選中項 ＝ -1)
  返回 ()
.如果真結束
待替換文件列表框.刪除表項 (待替換文件列表框.現行選中項)
.子程序 _待替換文件列表框_右鍵單擊表項
加入.禁止 ＝ 真
彈出菜單 (程序, , )
加入.禁止 ＝ 假
.子程序 _文件框1_鼠標右鍵被放開, 邏輯型
.參數 橫向位置, 整數型
.參數 縱向位置, 整數型
.參數 功能鍵狀態, 整數型
刪除.禁止 ＝ 真
清空待替換文件.禁止 ＝ 真
彈出菜單 (程序, , )
清空待替換文件.禁止 ＝ 假
刪除.禁止 ＝ 假
.子程序 _清空待替換文件_被選擇
待替換文件列表框.全部刪除 ()
.子程序 _退出_被選擇
結束 ()
.子程序 _執行按鈕_被單擊
.局部變量 查找文本, 文本型
.局部變量 替換文本, 文本型
.局部變量 搜尋位置
.局部變量 失敗數
.局部變量 cs
.局部變量 zs
.如果真 (待替換文件列表框.取表項數 () ＝ 0)
  返回 ()
.如果真結束
.如果真 (覆蓋原文件選擇框.選中 ＝ 假)
  .如果真 (刪全部空 (輸出目錄編輯框.內容) ＝ “”)
    信息框 (“請選擇輸出目錄!”, 48, )
    返回 ()
  .如果真結束
.如果真結束
.如果真 (刪全部空 (查找文本編輯框.內容) ＝ “”)
  信息框 (“請填寫欲尋找的文本!”, 48, )
  返回 ()
.如果真結束
置等待鼠標 ()
sj1 ＝ 取啟動時間 ()
編輯框3.內容 ＝ “”
進度條1.位置 ＝ 0
進度條1.最大位置 ＝ 待替換文件列表框.取表項數 ()
待替換文件列表框.現行選中項 ＝ -1
當前被搜尋文本 ＝ 查找文本編輯框.內容
zs ＝ 待替換文件列表框.取表項數 ()
.判斷循環首 (待替換文件列表框.現行選中項 ≠ 待替換文件列表框.取表項數 () － 1)
  待替換文件列表框.現行選中項 ＝ 待替換文件列表框.現行選中項 ＋ 1
  編輯框.內容 ＝ 取字節集數據 (讀入文件 (待替換文件列表框.取標題 (待替換文件列表框.現行選中項, )), #文本型)
  編輯框3.加入文本 (“正在替換：” ＋ 待替換文件列表框.取標題 (待替換文件列表框.現行選中項, ) ＋ #換行符)
  .如果真 (搜尋 (假) ＝ 假)
    編輯框.內容 ＝ 文本替換 (編輯框.內容, 編輯框.起始選擇位置 ＋ 1, 取文本長度 (查找文本編輯框.內容), 替換文本編輯框.內容)
    cs ＝ cs ＋ 1
  .如果真結束
  .判斷循環首 (搜尋 (真) ＝ 假)
    編輯框.內容 ＝ 文本替換 (編輯框.內容, 編輯框.起始選擇位置 ＋ 1, 取文本長度 (查找文本編輯框.內容), 替換文本編輯框.內容)
    cs ＝ cs ＋ 1
    編輯框.起始選擇位置 ＝ 起始
  .判斷循環尾 ()
  .如果 (覆蓋原文件選擇框.選中 ＝ 假)
    .如果 (寫到文件 (輸出目錄編輯框.內容 ＋ “\” ＋ 取文本右邊 (待替換文件列表框.取標題 (待替換文件列表框.現行選中項, ), 取文本長度 (待替換文件列表框.取標題 (待替換文件列表框.現行選中項, )) － 倒找文本 (待替換文件列表框.取標題 (待替換文件列表框.現行選中項, ), “\”, , 真)), 到字節集 (編輯框.內容)) ＝ 真)
      編輯框3.加入文本 (“完成,替換數量” ＋ 到文本 (cs) ＋ “處” ＋ #換行符)
    .否則
      編輯框3.加入文本 (“寫到文件失敗！” ＋ #換行符)
      失敗數 ＝ 失敗數 ＋ 1
    .如果結束
  .否則
    .如果 (寫到文件 (待替換文件列表框.取標題 (待替換文件列表框.現行選中項, ), 到字節集 (編輯框.內容)) ＝ 真)
      編輯框3.加入文本 (“完成,替換數量” ＋ 到文本 (cs) ＋ “處” ＋ #換行符)
    .否則
      編輯框3.加入文本 (“覆蓋原文件失敗！” ＋ #換行符)
      失敗數 ＝ 失敗數 ＋ 1
    .如果結束
  .如果結束
  待替換文件列表框.刪除表項 (待替換文件列表框.現行選中項)
  進度條1.位置 ＝ 進度條1.位置 ＋ 1
  cs ＝ 0
.判斷循環尾 ()
進度條1.位置 ＝ 進度條1.最大位置
sj2 ＝ (取啟動時間 () － sj1) ÷ 1000
編輯框3.加入文本 (#換行符 ＋ “-------------------------------” ＋ #換行符 ＋ “★完畢，總數目：” ＋ 到文本 (zs) ＋ “,” ＋ 到文本 (失敗數) ＋ “個文件沒有替換成功,總用時” ＋ 到文本 (sj2) ＋ “秒”)
待替換文件列表框.現行選中項 ＝ -1
恢復鼠標 ()
.子程序 搜尋, 邏輯型
.參數 是否為搜尋下一個, 邏輯型
搜尋位置 ＝ 編輯框.起始選擇位置 ＋ 1
.如果真 (是否為搜尋下一個)
  搜尋位置 ＝ 搜尋位置 ＋ 取文本長度 (替換文本編輯框.內容)
.如果真結束
.如果 (是否為搜尋下一個)
  搜尋位置 ＝ 尋找文本 (編輯框.內容, 當前被搜尋文本, 搜尋位置, 不區分大小寫選擇框.選中)
.否則
  搜尋位置 ＝ 倒找文本 (編輯框.內容, 當前被搜尋文本, 搜尋位置, 不區分大小寫選擇框.選中)
.如果結束
.如果 (搜尋位置 ＝ -1)
  返回 (真)
.否則
  編輯框.起始選擇位置 ＝ 搜尋位置 － 1
  編輯框.被選擇字符數 ＝ 取文本長度 (當前被搜尋文本)
  起始 ＝ 編輯框.起始選擇位置
  返回 (假)
.如果結束
.子程序 _輸出目錄按鈕_被單擊
.局部變量 ml, 文本型
ml ＝ 瀏覽文件夾 (“請選擇輸出目錄”, )
輸出目錄編輯框.內容 ＝ ml
.子程序 _覆蓋原文件選擇框_被單擊
.如果 (覆蓋原文件選擇框.選中 ＝ 真)
  輸出目錄編輯框.禁止 ＝ 真
  輸出目錄編輯框.背景顏色 ＝ #銀白
  輸出目錄按鈕.禁止 ＝ 真
.否則
  輸出目錄編輯框.禁止 ＝ 假
  輸出目錄編輯框.背景顏色 ＝ #白色
  輸出目錄按鈕.禁止 ＝ 假
.如果結束
.子程序 _關于_被選擇
信息框 (“文本批量替換機        ” ＋ #換行符 ＋ #換行符 ＋ “版本：1.0” ＋ #換行符, #信息圖標, )
.子程序 _刷新目錄_被選擇
_類型組合框_列表項被選擇 ()
.子程序 __啟動窗口_創建完畢
XP風格 (1)