Shader "Custom/MaskTexture"
{
  Properties
  {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Main Tex", 2D) = "white" {}
 _BumpMap("Normal Map", 2D) = "white" {}
 _BumpScale("Bump Scale", Float) = 1.0
 _SpecularMask("Specular Mask", 2D) = "white" {}
 _SpecularScale("Specular Scale", Float) = 1.0
 _Specular("Specular", Color) = (1,1,1,1)
 _Gloss("Gloss", Range(8.0, 256)) = 20
 }
 
 SubShader
 {
 Pass
 {
  Tags{"LightMode" = "ForwardBase"}
 
  CGPROGRAM
 
  #pragma vertex vert
  #pragma fragment frag
  #include "UnityCG.cginc"
  #include "Lighting.cginc"
 
  fixed4 _Color;
  sampler2D _MainTex;
  float4 _MainTex_ST;   //紋理變量名+_ST為unity內置宏，存儲了該紋理的縮放大小和偏移量，分別對應.xy和.zw屬性
  sampler2D _BumpMap;
  float _BumpScale;    //控制凹凸程度的變量
  sampler2D _SpecularMask; //遮罩紋理
  float _SpecularScale;  //控制遮罩紋理的可見度
  fixed4 _Specular;
  float _Gloss;
 
  struct a2v {
  float4 vertex : POSITION;
  float3 normal : NORMAL;
  float4 tangent : TANGENT;
  float4 texcoord : TEXCOORD0;
  };
 
  struct v2f {
  float4 pos : SV_POSITION;
  float2 uv : TEXCOORD0;
  float3 lightDir : TEXCOORD1;
  float3 viewDir : TEXCOORD2;
  };
 
  v2f vert(a2v v)
  {
  v2f o;
 
  o.pos = UnityObjectToClipPos(v.vertex);
  //將_MainTex紋理信息(縮放大小和偏移量以及坐標信息)存儲到o.uv.xy中
  o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
 
  //unity內置宏，計算并得到從模型空間到切線空間的變換矩陣rotation
  TANGENT_SPACE_ROTATION;
  //獲取切線空間下的光照方向
  o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
  //獲取切線空間下的視角方向
  o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;;
 
  return o;
  }
 
  fixed4 frag(v2f i) : SV_Target
  {
  //將切線空間下的光照方向和視角方向單位化
  fixed3 tangentLightDir = normalize(i.lightDir);
  fixed3 tangentViewDir = normalize(i.viewDir);
 
  //獲取切線空間下的法向量
  fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
  tangentNormal.xy *= _BumpScale;
  tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
 
  //獲取片元上的主紋理，并和變量_Color相乘得到其混合結果
  fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
  //獲取環境光
  fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
  //漫反射計算
  fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
 
  //高光反射計算，其計算方式跟前文的計算一樣，這里只能另外跟specularMask的遮罩紋理相乘得到其與遮罩紋理的混合結果
  fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
  fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;
  fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss) * specularMask;
 
  return fixed4(ambient + diffuse + specular, 1.0);
  }
 
  ENDCG
 }
  }
  FallBack "Specular"
}