Transpose如何限制數組行列轉置

這篇文章主要為大家展示了“Transpose如何限制數組行列轉置”，內容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領大家一起研究并學習一下“Transpose如何限制數組行列轉置”這篇文章吧。

提到數組，大家都不陌生，什么是數組行列轉置呢？其實也很簡單，如下圖所示，行列轉置就是將數組元素的存放方式進行轉換，原來保存在第一列的數據，將保持在新數組的第一行，并且保持原有順序，即6在第一個位置，8在最后一個位置。其他列依次類推。

在Excel工作表中有個強大的函數Transpose，可以直接實現數組行列轉置，作為VBA開發者來說，肯定不會忘記用這個。

Sub Demo1()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aTrans = Application.Transpose(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

一句代碼輕松實現轉置，比很多程序開發語言都要簡單，在本地窗口中可以看到轉置效果。

這么好用的神奇代碼，有時會莫名其妙的罷工，我們來看看下面的代碼，運行代碼將給出“類型不匹配”的錯誤提示，錯誤號為“13”。

Sub Demo2()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = Application.Transpose(aData)  ' Runtime error "13"
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

轉置失敗的原因在于aData(1,1)的字符長度為256，Transpose所能夠處理的數組元素字符長度最大為255。有時就是需要處理這樣的數組元素，那么我們可以使用自定義函數進行數組的行列轉置。TrasnposeArray可以實現二維數組的行列轉置。其效果與Transpose函數相同。

Sub Demo3()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = TransposeArray(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub
 
Function TransposeArray(arrA) As Variant
  Dim aRes()
  If VBA.IsArray(arrA) Then
    ReDim aRes(LBound(arrA, 2) To UBound(arrA, 2), LBound(arrA, 1) To UBound(arrA, 1))
    For i = LBound(arrA, 1) To UBound(arrA, 1)
      For j = LBound(arrA, 2) To UBound(arrA, 2)
        aRes(j, i) = arrA(i, j)
      Next
    Next
    TransposeArray = aRes
  End If
End Function

補充說明一點，由于Transpose本身是工作表函數，因此大家使用時，需要注意它的另一個限制，就是被轉置數組的最大行數是65,536。

以上是“Transpose如何限制數組行列轉置”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！