溫馨提示×
您好，登錄后才能下訂單哦！
點擊 登錄注冊 即表示同意《億速云用戶服務條款》
您好，登錄后才能下訂單哦！
這篇文章主要介紹了如何使用XSL和ASP在線編輯XML文檔，具有一定借鑒價值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。
本文通過一個詳細的例子，來闡述了在線編輯XML文檔數據的方法。由于Netscape對XML的支持比較弱，因此，要實現跨平臺的數據交換，數據的處理必須在服務器端進行。要編輯XML文檔，首先要做的事情就是怎樣把這些數據提取并顯示給訪問者，XSL為我們顯示XML文件提供了一個很好的解決方案。下面的例子就是利用XSL樣式單把XML文檔顯示出來，供用戶進行編輯，然后再把編輯后的數據提交到服務器，在服務器端進行數據的http://www.php.cn/php/php-tp-renewal.html" target="_blank">更新。這里采用ASP（Active Server Pages）來完成我們的任務。
首先，載入我們要進行編輯的XML文檔，利用微軟的文檔對象模型（Microsoft XMLDOM Object）和XSL，XML文檔就可以在服務器端轉換成可以在客戶端顯示的HTML文件內容。下面先看看我們使用的XML和XSL文件是什么樣子的。
XML文件：userdata.xml
<?xml version="1.0" encoding="gb2312"?> <用戶資料> <field id="姓名" taborder="1"> <field_value>孟子</field_value> </field> <field id="性別" taborder="2"> <field_value>男</field_value> </field> <field id="單位名稱" taborder="3"> <field_value>中國網絡技術發展公司北京分公司</field_value> </field> <field id="詳細地址" taborder="4"> <field_value>北京市嘉里中心102層</field_value> </field> <field id="電話" taborder="5"> <field_value>1391139136*</field_value> </field> <field id="電子郵件" taborder="6"> <field_value>amxh@21cn.com</field_value> </field> </用戶資料> XSL文件：userdata.xsl <?xml version="1.0" encoding="gb2312" ?> <xsl:stylesheet xmlns:xsl="http://www.w3.org/TR/WD-xsl"> <xsl:template match="/"> <html> <meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> <body> <form method="post" action="Edituserdata.asp"> <h2>用戶資料編輯：</h2> <table border="1" cellpadding="2"> <xsl:for-each select="用戶資料/field"> <tr> <td> <xsl:value-of select="@id"/> </td> <td> <input type="text"> <xsl:attribute name="id"> <xsl:value-of select="@id" /> </xsl:attribute> <xsl:attribute name="name"><xsl:value-of select="@id" /> </xsl:attribute> <xsl:attribute name="value"> <xsl:value-of select="field_value" /> </xsl:attribute></input> </td> </tr> </xsl:for-each> </table> <br /> <input type="submit" id="btnSubmit" name="btnSubmit" value="完成編輯" /> </form> </body> </html> </xsl:template> </xsl:stylesheet>
XSL文件使用了XSL：for-each元素的來遍歷整個XML文件，XML文件里每個“field”元素的“id”屬性和HTML表單的文本輸入框的“id”和“name”想對應。這樣，HTML表單的文本輸入框就顯示出了XML文件的元素值。此文件負責XML文檔在服務器端的轉換，以便能在各種瀏覽器上顯示。
下面是關鍵的程序，它實現打開和更新XML文檔的功能，并根據表單的提交與否，來決定是否進行更新。它包含了兩個函數，loadXMLFile負責載入和轉換要顯示的XML文件；updateXML函數負責更新XML文件。
Edituserdata.asp程序如下：
<%
'-----------------------------------------------------------
'定義函數 loadXMLFile(),接收二個參數：
'strXMLFile - XML 文件的路徑和文件名字
'strXSLFilee - XSL 文件的路徑和文件名字
'-----------------------------------------------------------
Function loadXMLFile(strXMLFile, strXSLFile)
'Declare local variables
Dim objXML
Dim objXSL
'實例化 XMLDOM 對象，以便載入 XML 文件。
set objXML = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objXML.async = false
'載入 XML 文件！
objXML.load(strXMLFile)
'實例化 XMLDOM 對象，以便載入 XSL 文件。
set objXSL = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objXSL.async = false
'載入 XSL 文件！
objXSL.load(strXSLFile)
'利用 XMLDOM 的 transformNode 方法，把 XSL 樣式表應用到 XML 文檔，然后輸出到客戶端。
Response.Write(objXML.transformNode(objXSL))
End Function
'------------------------------------------------------------------
'函數 updateXML() 接收一個參數：strXMLFile - XML 文件的路徑和文件名。
'------------------------------------------------------------------
Function updateXML(strXMLFile)
'聲明局部變量。
Dim objDom
Dim objRoot
Dim objField
Dim x
'實例化 XMLDOM 對象。
set objDOM = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objDOM.async = false
'載入 XML 文件。
objDOM.load strXMLFile
'設定根元素。
Set objRoot = objDom.documentElement
'遍歷 FORM 集合，并把提交的數據寫入 XML 文件。
For x = 1 to Request.Form.Count
'檢查提交的數據是否包含按鈕。如果是，忽略此數據。
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'按照 XSL 查詢模式，建立 objField 變量，把表單的元素對應到 XML 文檔里的相應元素[field_value]。
Set objField = objRoot.selectSingleNode("field[@id='" & Request.Form.Key(x) & "']/field_value")
'把表單提交的數據和 XML 文檔里的節點值對應起來。
objField.Text = Request.Form(x)
End If
Next
'保存編輯過的 XML 文件。
objDom.save strXMLFile
'釋放所有對對象的引用。
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
'調用 loadXMLFile 函數，把新編輯后的 XML 文件用 updateduserdata.xsl 樣式單顯示到客戶端。
loadXMLFile strXMLFile,server.MapPath("updateduserdata.xsl")
End Function
'檢查表單是否成功提交，如提交，更新 XML 文件；否則，轉到編輯狀態。
If Request.Form("btnSubmit") = "" Then
loadXMLFile server.MapPath("userdata.xml"),server.MapPath("userdata.xsl")
Else
updateXML server.MapPath("userdata.xml")
End If
%>當表單提交成功后，我們用updateduserdata.xsl來顯示我們剛剛編輯的數據。
updateduserdata.xsl如下：
<?xml version="1.0" encoding="gb2312" ?> <xsl:stylesheet xmlns:xsl="http://www.w3.org/TR/WD-xsl"> <xsl:template match="/"> <html> <meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> <body> <h2>更新后的用戶資料如下：</h2> <table border="1" cellpadding="2"> <xsl:for-each select="用戶資料/field"> <tr> <td> <xsl:value-of select="@id" /> </td> <td> <xsl:value-of select="field_value" /> </td> </tr> </xsl:for-each> </table> <form> <input type="button" value="返回" onclick="history.go(-1)" /> </form> </body> </html> </xsl:template> </xsl:stylesheet>
感謝你能夠認真閱讀完這篇文章，希望小編分享的“如何使用XSL和ASP在線編輯XML文檔”這篇文章對大家有幫助，同時也希望大家多多支持億速云，關注億速云行業資訊頻道，更多相關知識等著你來學習!
免責聲明：本站發布的內容（圖片、視頻和文字）以原創、轉載和分享為主，文章觀點不代表本網站立場，如果涉及侵權請聯系站長郵箱：is@yisu.com進行舉報，并提供相關證據，一經查實，將立刻刪除涉嫌侵權內容。
